# Checker for J4

# Check orders from definition
chor 1 2
chor 2 4
mu 1 2 3
chor 3 37
mu 3 2 4
mu 3 4 5
chor 5 10

# Find a 2A element z by powering up an element of order 24.
# Then az^g has odd order for some g, so a is in 2A as well.
mu 3 5 6
chor 6 24
pwr 12 6 7
mu 4 2 8
mu 8 8 9
cj 7 9 10
mu 1 10 11
chor 11 11

# Construct some elements in C(b^2) (an involution centralizer)
mu 3 8 12
mu 3 3 13
mu 12 13 14
mu 2 2 15
cj 15 14 16
mu 15 16 17
pwr 5 17 18
mu 14 18 19    # This element is in C(b^2)
mu 4 8 20
mu 20 4 21
mu 21 3 22
cj 15 22 23
mu 15 23 24
mu 22 24 25    # This element is in C(b^2)

# Use these elements to construct an element in C(b) with
# order divisible by 5. The centralizers of 4B and 4C have
# orders which are not divisible by 5, which proves that
# b is in 4A.
mu 25 19 26
mu 19 26 27
pwr 3 27 28
pwr 4 26 29
mu 28 29 30
mu 30 25 31
chor 31 20     # This element has order dividing 5...
com 31 2 32
chor 32 1      # ...and it commutes with b.
