目录

# AGGREGATE 函数

此函数返回区域内计算的聚合结果。您可以使用下面列出的不同聚合函数。「聚合函数」允许您在计算中省略隐藏的行、错误、SUBTOTAL 和其他 AGGREGATE 函数的结果.

「自动筛选」已激活时，AGGREGATE 函数应用于数据的垂直范围。如果未激活「自动筛选」, 函数结果的自动重新计算不适用于新隐藏的行。尽管并非如此设计, 但可以应用于水平范围, 略有限制。即, 应用于水平数据范围的 AGGREGATE 函数无法识别隐藏列, 但可正确地忽略嵌入行中的 SUBTOTAL 函数和其他 AGGREGATE 函数的错误和结果。

### 语法

AGGREGATE(Function; Option; Number 1[; Number 2][; ... ;[Number 253]])

或

AGGREGATE(Function; Option; Array[; k])

函数 – 必填参数。函数索引或对值为 1 到 19 的单元格的引用, 如下表所示。

函数索引 | 应用的函数
--- | ---
1 | AVERAGE
2 | COUNT
3 | COUNTA
4 | MAX
5 | MIN
6 | PRODUCT
7 | STDEV.S
8 | STDEV.P
9 | SUM
10 | VAR.S
11 | VAR.P
12 | MEDIAN
13 | MODE.SNGL
14 | LARGE
15 | SMALL
16 | PERCENTILE.INC
17 | QUARTILE.INC
18 | PERCENTILE.EXC
19 | QUARTILE.EXC

Option – 必填参数。选项索引或对值为 0 到 7 的单元格的引用，确定函数范围中忽略的内容。

选项索引 | 应用的选项
--- | ---
0 | 只忽略嵌套的 SUBTOTAL 与 AGGREGATE 函数
1 | 只忽略隐藏的行、嵌套的 SUBTOTAL 与 AGGREGATE 函数
2 | 只忽略错误、嵌套的 SUBTOTAL 与 AGGREGATE 函数
3 | 忽略隐藏的行、错误以及嵌套的 SUBTOTAL 与 AGGREGATE 函数
4 | 不忽略
5 | 只忽略隐藏的行
6 | 只忽略错误
7 | 只忽略隐藏的行与错误

Number1 – required argument. The first numeric argument (if the range is set by a list of values inside the function) or a reference to a cell that contains it.

Number2, 3, ... – optional. A numeric argument or a reference to a cell (up to 253 arguments), for which you need the aggregate value.

Array – required argument. The array can be specified by the boundaries of the range, the name of the named range or the column label.

对于列标签的使用, 需要启用「自动查找列和行标签」功能。

k – required argument for the following functions: LARGE, SMALL, PERCENTILE.INC, QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC. It is a numeric argument, which must correspond to the second argument of these functions.

### 示例

| A | B | C
1 | 「第一列」 | 「第二列」 | 「第三列」
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #DIV/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #VALUE! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGGREGATE(4;2;A2:A9)
Returns maximum value for the range A2:A9 = 34.

「=AGGREGATE(9;5;A5:C5)」
返回范围 A5:C5 的总和 = 29, 即使某些列是隐藏的。

「=AGGREGATE(9;5;B2:B9)」
返回 B 列的总和 = 115。如果任何行被隐藏, 该函数将忽略其值, 例如, 如果第 7 行处于隐藏状态, 则该函数将返回 95。

如果需要将该函数应用于 3D 范围, 本示例演示如何执行此操作。

「=AGGREGATE(13;3;Sheet1.B2:B9:Sheet3.B2:B9)」
函数返回工作表 1:3 中第二列值的众数 (数据相同) = 8。

可以对公式中的每个参数使用指向单元格或区域的引用。下面的示例演示它的工作原理。它还同时展示，可以使用列标签来指定数组。

「=AGGREGATE(E3;E5;'ColumnOne')」
如果 E3 = 13 且 E5 = 5, 则该函数返回第一列的众数 = 10。

#### Technical information

This function is available since LibreOffice 4.4.

This function is NOT part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.AGGREGATE

相关主题

AGGREGATE wiki page.

AVERAGE, COUNT, COUNTA, MAX, MIN, PRODUCT, STDEV.S, STDEV.P, SUM, VAR.S, VAR.P, MEDIAN, MODE.SNGL, LARGE, SMALL, PERCENTILE.INC , QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC

自动查找列与行标签

请支持我们!