Зміст

# Фінансові функції, перша частина

Ця категорія містить математичні фінансові функції на LibreOffice Calc.

## ACCRINT

Повертає накопичений дохід для цінних паперів у разі періодичних платежів.

#### Syntax

ACCRINT(Issue; FirstInterest; Settlement; Rate; [Par]; Frequency [; Basis])

Випуск (обов'язково) - дата випуску цінних паперів.

ПершаВиплата (обов'язково) – дата перших відсотків за цінними паперами.

Угода – дата розрахунку накопиченого доходу.

Ставка (обов'язково) – щорічний рівень номінальної ставки (купонної ставки).

Номінал (не обов'язково) - номінальна вартість цінного паперу. Якщо не вказано, то підставляється типове значення 1000.

We recommend that you always specify the value that you require for ACCRINT’s Par argument, rather than allowing Calc to apply an arbitrary default. This will make your formula easier to understand and easier to maintain.

Періодичність – кількість виплат доходів за відсотками на рік (1, 2 або 4).

Basis (optional) is chosen from a list of options and indicates how the year is to be calculated.

Basis | Calculation
--- | ---
0 or missing | US method (NASD), 12 months of 30 days each
1 | Exact number of days in months, exact number of days in year
2 | Exact number of days in month, year has 360 days
3 | Exact number of days in month, year has 365 days
4 | European method, 12 months of 30 days each

#### Example

Цінні папери придбані 28.02.01. Дата нарахування перших відсотків – 31.08.2001. Дата виплати відсотків – 01.05.01. Відсоткова ставка дорівнює 10% (0,1), а номінал становить 1000 грошових одиниць. Відсотки виплачуються раз на півроку (частота 2). Базис – американський спосіб (0). Скільки становить накопичений відсоток?

=ACCRINT("2001-02-28";"2001-08-31";"2001-05-01";0.1;1000;2;0) повертає значення 16,94444.

## ACCRINTM

Розраховує накопичений дохід для цінних паперів у разі разового платежу на дату угоди.

#### Syntax

ACCRINTM(Issue; Settlement; Rate [; Par [; Basis]])

Дата випуску (обов'язкова) дата випуску цінних паперів.

Угода (обов'язково) – дата розрахунку накопиченого доходу.

Ставка (обов'язково) – щорічний рівень номінальної ставки (купонної ставки).

Номінал (не обов'язково) - номінальна вартість цінного паперу. Якщо не вказано, то підставляється типове значення 1000.

We recommend that you always specify the value that you require for ACCRINTM’s Par argument, rather than allowing Calc to apply an arbitrary default. This will make your formula easier to understand and easier to maintain.

Basis (optional) is chosen from a list of options and indicates how the year is to be calculated.

Basis | Calculation
--- | ---
0 or missing | US method (NASD), 12 months of 30 days each
1 | Exact number of days in months, exact number of days in year
2 | Exact number of days in month, year has 360 days
3 | Exact number of days in month, year has 365 days
4 | European method, 12 months of 30 days each

#### Example

Дата випуску цінного паперу – 01.04.2001. Дата погашення – 15.06.2001. Відсоткова ставка рівна 10% або 0,1, а номінал – 1000 грошових одиниць. Базис для нарахування добових або річних відсотків – щоденний залишок (3). Скільки становитимуть накопичені відсотки?

=ACCRINTM("2001-04-01";"2001-06-15";0.1;1000;3) повертає 20.54795.

## AMORDEGRC

Повертає величину дегресивної амортизації за платіжний період. На відміну від AMORLINC для цієї функції використовується коефіцієнт амортизації, що не залежить від періоду амортизації.

#### Syntax

AMORDEGRC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])

Вартість – початкова вартість.

ДатаПридбання – дата купівлі.

ПершийПеріод – дата закінчення першого платіжного періоду.

ЗалишковаВартість – ліквідаційна вартість майна у кінці періоду амортизації.

Період – розглядуваний платіжний період.

Ставка – ставка амортизації у відсотках.

Basis (optional) is chosen from a list of options and indicates how the year is to be calculated.

Basis | Calculation
--- | ---
0 or missing | US method (NASD), 12 months of 30 days each
1 | Exact number of days in months, exact number of days in year
2 | Exact number of days in month, year has 360 days
3 | Exact number of days in month, year has 365 days
4 | European method, 12 months of 30 days each

#### Example

An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming degressive depreciation, what is the amount of depreciation in the fourth depreciation period?

=AMORDEGRC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 163 currency units.

Be aware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.

## AMORLINC

Служить для розрахунку величини лінійної амортизації за розрахунковий період. Якщо капітал набутий протягом платіжного періоду, використовується пропорційно розподілена амортизація.

#### Syntax

AMORLINC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])

Вартість – початкова вартість.

Дата придбання – дата купівлі.

Перший термін – дата закінчення першого платіжного періоду.

Залишкова вартість – ліквідаційна вартість майна у кінці періоду амортизації.

Період – розглядуваний платіжний період.

Ставка – ставка амортизації у відсотках.

Basis (optional) is chosen from a list of options and indicates how the year is to be calculated.

Basis | Calculation
--- | ---
0 or missing | US method (NASD), 12 months of 30 days each
1 | Exact number of days in months, exact number of days in year
2 | Exact number of days in month, year has 360 days
3 | Exact number of days in month, year has 365 days
4 | European method, 12 months of 30 days each

#### Example

An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming linear depreciation, what is the amount of depreciation in the fourth depreciation period?

=AMORLINC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 200 currency units.

Be aware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.

## DB

Returns the depreciation of an asset for a specified period using the fixed-declining balance method.

This form of depreciation is used if you want to get a higher depreciation value at the beginning of the depreciation (as opposed to linear depreciation). The depreciation value is reduced with every depreciation period by the depreciation already deducted from the initial cost.

#### Syntax

DB(Cost; Salvage; Life; Period [; Month])

Cost is the initial cost of an asset.

Salvage is the value of an asset at the end of the depreciation.

Life defines the period over which an asset is depreciated.

Period is the length of each period. The length must be entered in the same date unit as the depreciation period.

Month (optional) denotes the number of months for the first year of depreciation. If an entry is not defined, 12 is used as the default.

#### Example

A computer system with an initial cost of 25,000 currency units is to be depreciated over a three-year period. The salvage value is to be 1,000 currency units. The first period of depreciation comprises 6 months. What is the fixed-declining balance depreciation of the computer system in the second period, which is a full year starting from the end of the first six-month period?

=DB(25000; 1000; 3; 2; 6) returns 11,037.95 currency units.

## DDB

Returns the depreciation of an asset for a specified period using the arithmetic-declining method.

Use this form of depreciation if you require a higher initial depreciation value as opposed to linear depreciation. The depreciation value gets less with each period and is usually used for assets whose value loss is higher shortly after purchase (for example, vehicles, computers). Please note that the book value will never reach zero under this calculation type.

#### Syntax

DDB(Cost; Salvage; Life; Period [; Factor])

Cost fixes the initial cost of an asset.

Salvage fixes the value of an asset at the end of its life.

Life is the number of periods (for example, years or months) defining how long the asset is to be used.

Period states the period for which the value is to be calculated.

Factor (optional) is the factor by which depreciation decreases. If a value is not entered, the default is factor 2.

#### Example

A computer system with an initial cost of 75,000 currency units is to be depreciated monthly over 5 years. The value at the end of the depreciation is to be 1 currency unit. The factor is 2.

=DDB(75000;1;60;12;2) = 1,721.81 currency units. Therefore, the double-declining depreciation in the twelfth month after purchase is 1,721.81 currency units.

## DISC

Призначена для розрахунку відсотка знижки на цінні папери.

#### Syntax

DISC(Settlement; Maturity; Price; Redemption [; Basis])

Угода – дата придбання цінних паперів.

Погашення – дата, коли настає термін погашення.

Вартість – вартість цінних паперів на кожні 100 грошових одиниць номіналу.

Викуп – викупна вартість цінних паперів на кожні 100 грошових одиниць номіналу.

Basis (optional) is chosen from a list of options and indicates how the year is to be calculated.

Basis | Calculation
--- | ---
0 or missing | US method (NASD), 12 months of 30 days each
1 | Exact number of days in months, exact number of days in year
2 | Exact number of days in month, year has 360 days
3 | Exact number of days in month, year has 365 days
4 | European method, 12 months of 30 days each

#### Example

Цінні папери придбано 25.01.01; дата погашення –15.11.01. Ціна (придбання) становить 97, ціна дострокового викупу становить 100 грошових одиниць. Потрібно визначити суму розрахунку на основі щоденного нарахування відсотків (базис 3).

=DISC("2001-01-25";"2001-11-15";97;100;3) повертає значення 0,0372 або 3,72%.

## DURATION

Служить для розрахунку терміну до погашення цінних паперів з фіксованим відсотком в роках.

#### Syntax

DURATION(Settlement; Maturity; Coupon; Yield; Frequency [; Basis])

Угода – дата придбання цінних паперів.

Погашення – дата, коли настає термін погашення.

Купон – щорічний рівень купонної ставки (номінальної ставки).

Дохід – щорічний дохід від цінних паперів.

Частота – кількість виплат доходів за відсотками в рік (1, 2 або 4).

Basis (optional) is chosen from a list of options and indicates how the year is to be calculated.

Basis | Calculation
--- | ---
0 or missing | US method (NASD), 12 months of 30 days each
1 | Exact number of days in months, exact number of days in year
2 | Exact number of days in month, year has 360 days
3 | Exact number of days in month, year has 365 days
4 | European method, 12 months of 30 days each

#### Example

Цінні папери придбано 01.01.01; термін погашення - 01.01.06. Купонна ставка становить 8%. Дохід становить 9,0%. Відсотки виплачуються раз на півроку (частота 2). Яким буде термін до погашення на основі щоденного нарахування відсотків (базис 3)?

=DURATION("2001-01-01";"2006-01-01";0.08;0.09;2;3) returns 4.2 years.

## EFFECT

Повертає річний фактичний відсоток для номінальної відсоткової ставки.

Номінальна відсоткова ставка - розмір відсоткової ставки на кінець розрахункового періоду. Фактична відсоткова ставка підвищується з кількістю здійснених платежів. Іншими словами, відсотки часто виплачуються у вигляді часткових платежів (наприклад, щомісяця або щокварталу) до кінця розрахункового періоду.

#### Syntax

EFFECT(Nom; P)

Ном – номінальна відсоткова ставка.

П - количество периодов выплат в год.

#### Example

Якщо щорічний рівень номінальної відсоткової ставки дорівнює 9,75% і визначено чотири періоди виплат, яка фактична відсоткова ставка?

=EFFECT(9.75%;4) = 10.11% The annual effective rate is therefore 10.11%.

## EFFECT_ADD

Служить для розрахунку щорічного рівня фактичної відсоткової ставки на основі номінальної відсоткової ставки і кількості виплат на рік.

Функції, назви яких закінчуються на _ADD або _EXCEL2003, повертають ті ж значення, що й відповідні функції Microsoft Excel 2003. Щоб отримати результати, засновані на міжнародних стандартах, слід використовувати функцію з назвою без суфікса.

#### Syntax

EFFECT_ADD(НомінальнаСтавка; Періоди)

НомінальнаСтавка – щорічний рівень номінальної відсоткової ставки.

Періоди – кількість виплат за ставками в рік.

#### Example

Який щорічний рівень фактичної відсоткової ставки при номінальній ставці в 5,25% і поквартальних виплатах?

=EFFECT_ADD(0,0525;4) повертає значення 0,053543 або 5,3543%.

## IRR

Calculates the internal rate of return for an investment. The values represent cash flow values at regular intervals, at least one value must be negative (payments), and at least one value must be positive (income).

If the payments take place at irregular intervals, use the XIRR function.

#### Syntax

IRR(Values [; Guess])

Values represents an array containing the values.

Припущення (необов'язково) - орієнтовна вартість. Для обчислення внутрішнього доходу використовується ітеративний метод. Якщо надається невелика кількість значень, то слід надати початкову орієнтовну вартість для початку циклу.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Example

Under the assumption that cell contents are A1=-10000, A2=3500, A3=7600 and A4=1000, the formula =IRR(A1:A4) gives a result of 11,33%.

Оскільки використовується ітеративний метод, IRR може повернути Помилку 523 з повідомленням "Помилка: обчислення не збігаються" в рядку стану. В такому разі спробуйте змінити значення Припущення.

## ISPMT

Calculates the level of interest for unchanged amortization installments.

#### Syntax

ISPMT(Rate; Period; TotalPeriods; Invest)

Rate sets the periodic interest rate.

Period is the number of installments for calculation of interest.

TotalPeriods is the total number of installment periods.

Invest is the amount of the investment.

#### Example

For a credit amount of 120,000 currency units with a two-year term and monthly installments, at a yearly interest rate of 12% the level of interest after 1.5 years is required.

=ISPMT(1%;18;24;120000) = -300 currency units. The monthly interest after 1.5 years amounts to 300 currency units.

## PV

Повертає поточну суму інвестиції після серії регулярних платежів.

Ця функція призначена для розрахунку суми, необхідної для інвестицій з фіксованим відсотком для отримання певної суми (річної ренти) за вказане число періодів. Можна також визначити, яка сума буде залишатися після закінчення періоду. Крім того, необхідно вказати час виплати суми: на початку чи в кінці кожного періоду.

Введіть значення у вигляді чисел, виразів або посилань. Наприклад, якщо щорічний відсоток становить 8%, але в якості періоду потрібно вказати місяць, введіть 8%/12 в поле Відсоток і LibreOffice Calc автоматично обчислить правильне значення.

#### Syntax

PV(Rate; NPer; Pmt [; FV [; Type]])

Ставка: відсоткова ставка за кожний період.

КПЕР - загальне число періодів (період сплати).

ПЛТ - виплата, яка здійснюється в кожний період.

МС (необов'язково) визначає майбутню суму, що залишилася після підсумкового платежу.

Тип (Необов'язково) визначає дату виконання платежів. Type = 1 означає, що виплата виконується на початку періоду, а Type = 0 (типове) означає, що виплата виконується в кінці періоду.

У функціях LibreOffice Calc необов'язкові параметри можна залишати порожніми лише тоді, коли після них немає інших параметрів. Наприклад, якщо функція має чотири параметри і два останні параметри не є обов'язковими, то можна залишити порожніми параметри 3 і 4 або параметр 4. Залишити порожнім параметр 3 не можна.

#### Example

Яка поточна вартість інвестицій, якщо щомісячні виплати становлять 500 грошових одиниць, а щорічна процентна ставка - 8%? Платіжний період - 48 місяців; в кінці розрахункового періоду має залишитися 20000 грошових одиниць.

=PV(8%/12;48;500;20000) = -35 019,37 грошових одиниць. За описаних вище умов на поточний момент необхідно вкласти 35 019,37 грошових одиниць, щоб щомісячні виплати становили 500 грошових одиниць протягом 48 місяців, а залишок на кінець періоду дорівнював 20 000 грошових одиниць. Перехресна перевірка показує, що 48 x 500 грошових одиниць + 20 000 грошових одиниць = 44 000 грошових одиниць. Різниця між цією сумою та вкладеною сумою, рівною 35 000 грошових одиниць, - виплачені відсотки.

Якщо замість значень у формулу ввести посилання, можна розрахувати будь-яке число сценаріїв типу "якщо-то". Зверніть увагу, що посилання на константи повинні бути визначені як абсолютні посилання. Приклади такого застосування функції можна знайти в описі функцій амортизації.

## RECEIVED

Повертає суму, отриману за цінними паперами з фіксованим відсотком у певний момент часу.

#### Syntax

RECEIVED(Settlement; Maturity; Investment; Discount [; Basis])

Угода – дата придбання цінних паперів.

Погашення – дата, коли настає термін погашення.

Інвестиція – сума придбання.

Скидка – відсоток скидки на придбання цінних паперів.

Basis (optional) is chosen from a list of options and indicates how the year is to be calculated.

Basis | Calculation
--- | ---
0 or missing | US method (NASD), 12 months of 30 days each
1 | Exact number of days in months, exact number of days in year
2 | Exact number of days in month, year has 360 days
3 | Exact number of days in month, year has 365 days
4 | European method, 12 months of 30 days each

#### Example

Дата угоди: 15 лютого 1999, дата погашення: 15 мая 1999, сума інвестиції: 1000 грошових одиниць, скидка: 5,75 відсотків, база: щоденний залишок/360 = 2.

Сума, отримана на дату погашення, розраховується так:

=RECEIVED("1999-02-15";"1999-05-15";1000;0.0575;2) повертає значення 1014,420266.

## SYD

Повертає відсоток амортизації, розрахований методом "суми чисел".

Ця функція служить для розрахунку величини амортизації для одного періоду повної амортизації для об'єкта. При амортизації методом "суми чисел" величина амортизації зменшується на фіксовану суму кожен період.

#### Syntax

SYD(Вартість; Залишкова вартість; Термін; Період)

Ціна - початкова ціна активу.

Залишок - ціна активу в кінці його амортизації.

Термін - період, протягом якого вартість активу амортизується.

Період: період, для якого розраховується амортизація.

#### Example

Відеосистема, початкова вартість якої становить 50000 грошових одиниць, амортизується щорічно протягом 5 років. Ліквідаційна вартість дорівнює 10000 грошових одиниць. Потрібно розрахувати амортизацію за перший рік.

=SYD(50000;10000;5;1)=13 333,33 грошових одиниць. Величина амортизації за перший рік – 13 333,33 грошових одиниць.

Щоб отримати загальне уявлення про відсоткові ставки амортизації за період, необхідно визначити таблицю амортизації. Вводячи різні формули розрахунку амортизації, доступні в Calc LibreOffice, можна вибрати найбільш підхожий метод амортизації. Введіть такі значення в таблицю:

| А | B | C | D | E
1 | Початкова вартість | Ліквідаційна вартість | Термін використання | Період часу | Аморт. SYD
2 | 50 000 грошових одиниць | 10 000 грошових одиниць | 5 | 1 | 13 333,33 грошових одиниць
3 |  |  |  | 2 | 10666,67 грошових одиниць
4 |  |  |  | 3 | 8 000,00 грошових одиниць
5 |  |  |  | 4 | 5 333,33 грошових одиниць
6 |  |  |  | 5 | 2 666,67 грошових одиниць
7 |  |  |  | 6 | 0,00 грошових одиниць
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | >0 |  |  | Разом | 40 000,00 грошових одиниць

Формула в комірці E2:

=SYD($A$2;$B$2;$C$2;D2)

Ця формула копіюється в усі комірки стовпця E до комірки E11 (виберіть комірку E2 і потяните за правый нижний угол, удерживая левую кнопку мыши).

Комірка E13 містить формулу для перевірки загальної величини амортизації. Для цього використовується функція SUMIF, оскільки від'ємні значення комірок E8:E11 не повинні враховуватися. Умова >0 міститься в комірці A13. Формула в комірці E13:

=SUMIF(E2:E11;A13)

Після цього можна розрахувати амортизацію за 10-річний період за ліквідаційної вартості 1 грошова одиниця або за іншої початкової вартості тощо.

Financial Functions Part Two

Financial Functions Part Three

Функції за категорією

Будь ласка, підтримайте нас!