Contenido

# Función PROMEDIO.SI.CONJUNTO

Devuelve la media aritmética de todas las celdas en un intervalo que satisfagan varios criterios. La función PROMEDIO.SI.CONJUNTO suma todos los resultados que coincidan con comprobaciones lógicas y divide esta suma por la cantidad de valores seleccionados.

Esta función está disponible a partir de la versión 4.0 de LibreOffice.

### Sintaxis

PROMEDIO.SI.CONJUNTO(Func_Range; Range1; Criterion1[; Range2; Criterion2][; … ; [Range127; Criterion127]])

Función_rango - argumento requerido. Es un rango de celdas, un nombre de un rango con nombre o una etiqueta de una columna o una fila que contiene valores para calcular la media.

Intervalo 1: argumento requerido. Es un intervalo de celdas, el nombre de un intervalo con nombre o la etiqueta de una columna o una fila a que se aplicará el criterio correspondiente.

Criterion1: A criterion is a text expression computed from a single cell Reference, Formula, Number or Text. It is used in comparisons with cell contents.

Una referencia a una celda vacía se interpreta como el valor numérico 0.

Una expresión coincidente puede ser:

- Un número o valor lógico. Un contenido de celda correspondiente equivale al número o valor lógico.

- A value beginning with a comparator (<, <=, =, >, >=, <>).

  En el caso de =, si el valor está vacío, coincide con las celdas vacías.

  En el caso de <>, si el valor está vacío, coincide con las celdas no vacías.

  For <>, if the value is not empty it matches any cell content except the value, including empty cells.

  Nota"=0" no coincide con las celdas vacías.

  For = and <>, if the value is not empty and can not be interpreted as a number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.

- Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Intervalo2: opcional. Intervalo2 y todos los argumentos siguientes tienen el mismo significado que Intervalo1.

Criterio 2 – Opcional. Criterio2 y todos los promedios significan lo mismo que Criterio.

La búsqueda admite tanto comodines como expresiones regulares. Si activa las expresiones regulares, puede introducir «tod.*», por ejemplo, para encontrar la primera localización de «tod» seguido de cualesquier caracteres. Si desea localizar un texto que es también una expresión regular, debe anteponer a cada uno de los metacaracteres u operadores de la expresión una contrabarra «\», o circundarlo con \Q...\E. Puede activar o desactivar la valoración automática de los comodines o las expresiones regulares en LibreOffice ▸ PreferenciasHerramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular.

Al utilizar funciones en las que uno o más argumentos son cadenas de criterios de búsqueda que representan una expresión regular, en primer lugar se intentará convertir los criterios de la cadena en números. Por ejemplo, «.0» se convertirá en 0.0 y así sucesivamente. Si el intento es fructuoso, la correspondencia no será por expresión regular, sino numérica. No obstante, si se cambia a una configuración regional en la cual el separador decimal no es el punto, pasará a valer la expresión regular. Para forzar la evaluación de la expresión regular en lugar de una expresión numérica, utilice una expresión que no pueda confundirse con un número, como por ejemplo «.\0» o «(?i).0».

Funcion_Rango y Rango 1, Rango 2...debe tener el mismo tamaño, de lo contrario, la función devuelve error: 502 - Argumento no válido.

La relación lógica entre los criterios puede definirse como Y lógico (conjunción). En otras palabras, si y sólo si se cumplen todos los criterios dados, un valor de la celda correspondiente delFunción_Rangose tiene en cuenta en el cálculo.

La función puede tener hasta 255 argumentos, lo que significa que es posible especificar hasta 127 intervalos de criterios y sus criterios correspondientes.

Si una celda contiene VERDADERO se tratará como 1; si contiene FALSO, como 0 (cero).

### Ejemplos

Tenga en cuenta la tabla siguiente

| A | B | C
1 | Nombre de producto | Sales | Revenue
2 | lápiz | 20 | 65
3 | bolígrafo | 35 | 85
4 | cuaderno | 20 | 190
5 | libro | 17 | 180
6 | estuche | no | no

En todos los ejemplos siguientes, los intervalos utilizados para el cálculo incluyen la fila n.º 6, pero se ignorará debido a que contiene texto.

#### Uso simple

=PROMEDIO.SI.CONJUNTO(B2:B6;B2:B6;">=20")

Calcula el promedio de los valores del intervalo B2:B6 que sean mayores o iguales a 20. Devuelve 25 porque la quinta fila no cumple con el criterio.

=PROMEDIO.SI.CONJUNTO(C2:C6;B2:B6;">=20";C2:C6;">70")

Calcula el promedio de los valores en el intervalo C2:C6 que sean mayores que 70 y se correspondan con las celdas en B2:B6 con valores mayores o iguales que 20. Devuelve 137,5, porque las filas segunda y quinta no cumplen con por lo menos un criterio.

#### Uso de expresiones regulares y funciones anidadas

=PROMEDIO.SI.CONJUNTO(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Calcula el promedio de los valores en el intervalo C2:C6 que se correspondan con todos los valores en el intervalo B2:B6, exceptuando el menor y el mayor. Devuelve 127,5, porque las filas tercera y quinta no cumplen con por lo menos un criterio.

PROMEDIO.SI.CONJUNTO(C2:C6;A2:A6;"pan.*";B2:B6;"<"&MAX(B2:B6))

Calcula el promedio de los valores del intervalo C2:C6 que se correspondan con todas las celdas del intervalo A2:A6 que comienzan por «pan» y a todas las celdas del intervalo B2:B6 excepto su máximo. Devuelve 65 porque solo la segunda fila cumple con todos los criterios.

#### Referencia a una celda como criterio

Si se necesita cambiar un criterio fácilmente, se puede especificar en una celda separada y usar una referencia a esa celda en la condición de la función PROMEDIO.SI.CONJUNTO. Por ejemplo, la función anterior se puede reescribir asi:

=PROMEDIO.SI.CONJUNTO(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Si E2 = pan, la función devuelve 65 porque el enlace a la celda se sustituye por su contenido.

#### Información técnica

Esta función forma parte del estándar Open Document Format for Office Applications (OpenDocument), versión 1.2 (ISO/IEC 26300:2-2015).

Temas relacionados

AVERAGEIFS wiki page.

PROMEDIO, PROMEDIOA, DESVPROM, PROMEDIO.SI

CONTAR.SI.CONJUNTO, Función MIN.SI.CONJUNTO, Función MAX.SI.CONJUNTO, PROMEDIO.SI.CONJUNTO, SUMAR.SI.CONJUNTO

Lista de expresiones regulares

¡Necesitamos su ayuda!