# Black box algorithm to find standard generators of Co1

	set F 0
	set G 0
	set V 0
lbl SEMISTD
	rand 1
	ord 1 A
	incr V
	if V gt 1000 then timeout
	if A notin 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 18 20 21 &
			22 23 24 26 28 30 33 35 36 39 40 42 60 then fail
	if F eq 0 then
		if A in 26 42 then
			div A 2 B
			pwr B 1 2
			set F 1
		endif
	endif
	if G eq 0 then
		if A in 9 18 36 then
			div A 3 C
			pwr C 1 3
			set G 1
		endif
	endif

	if F eq 0 then jmp SEMISTD
	if G eq 0 then jmp SEMISTD
	
	set X 0
lbl CONJUGATE
	incr X
	if X gt 2000 then timeout
	rand 4
	cjr 3 4
	mu 2 3 5
	ord 5 D
	if D notin 3 6 8 9 10 11 12 13 14 15 16 18 20 21 22 23 24 26 &
		28 30 33 35 36 39 40 42 60 then fail
	if D noteq 40 then jmp CONJUGATE

	mu 5 3 6  # abb
	mu 5 6 7  # ababb

	ord 7 E
	if E notin 6 21 then fail

	if E noteq 6 then jmp CONJUGATE

	oup 2 2 3
